單片機方案開發(fā)商深圳英銳恩分享PIC單片機內部EEPROM讀寫子程序。

;實戰(zhàn)《內部EEPROM讀寫實驗》

;本實戰(zhàn)的目的是讓大家熟悉PIC16F87X內部EEPROM的讀寫方法
;項目實現(xiàn)的功能：對于地址為00H-3FH的64個EEPROM數據存儲單元，
;分別將數據0-63依次燒寫進去，然后再循環(huán)讀出，顯示在8只LED發(fā)光二極管上
;程序文件名“MCD-EMP1.ASM”
;程序清單如下:
;************************************
STATUS   EQU 3H       ;定義狀態(tài)寄存器地址
RP0      EQU 5H       ;定義頁選位RP0的位地址
RP1      EQU 6H       ;定義頁選位RP1的位地址
Z        EQU 2H       ;定義0狀態(tài)位的位地址
PORTC    EQU 7H       ;定義RC口數據寄存器地址
TRISC    EQU 87H      ;定義RC口方向控制寄存器地址
EECON1   EQU 18CH     ;定義寫控制寄存器1的地址
EECON2   EQU 18DH     ;定義寫控制寄存器2的地址
EEDATA   EQU 10CH     ;定義讀/寫數據寄存器地址
EEADR    EQU 10DH     ;定義讀/寫地址寄存器地址
RD       EQU  0       ;定義讀啟動控制位位地址
WR       EQU  1       ;定義寫啟動控制位位地址
WREN     EQU  2       ;定義寫使能控制位位地址
EEPGD    EQU  7       ;定義訪問目標選擇控制位位址
F        EQU  1       ;定義目標寄存器為RAM的指示符
W        EQU  0       ;定義目標寄存器為W的指示符 

ADDR     EQU  70H     ;定義地址變量
DATA1    EQU  71H     ;定義數據變量
;*************************************
    ORG     0000H        ;
    NOP                  ;放置一條ICD必須的空操作指令
    GOTO    MAIN         ;
    ORG     0008H        ;
MAIN
    BCF     STATUS,RP1   ;選體1為當前體
    BSF     STATUS,RP0   ;
    MOVLW   00H          ;設定RC全部為輸出
    MOVWF   TRISC        ;
    BSF     STATUS,RP1   ;體3為當前體
    CLRF    ADDR         ;地址變量清0
    CLRF    DATA1        ;數據變量清0
WRITE
    BSF     STATUS,RP1   ;選定體3
    BTFSC   EECON1,WR    ;上一次寫操作是否完成
    GOTO    $-1          ;否！返回繼續(xù)檢測
    BCF     STATUS,RP0   ;選定體2
    MOVF    ADDR,W       ;取地址
    MOVWF   EEADR        ;送地址寄存器
    MOVF    DATA1,W      ;取數據
    MOVWF   EEDATA       ;送數據寄存器
    BSF     STATUS,RP0   ;選定體3
    BCF     EECON1,EEPGD ;選定EEPROM為訪問對向
    BSF     EECON1,WREN  ;開放寫操作使能控制
    MOVLW   55H         ; 

MOVWF   EECON2       ;送55H到寄存器EECON2（讀寫內部EEPROM，這句是固定的）
    MOVLW   0AAH         ;
    MOVWF   EECON2       ;送AAH到寄存器EECON2（讀寫內部EEPROM，這句是固定的）
    BSF     EECON1,WR    ;啟動寫操作
    BCF     EECON1,WREN  ;禁止寫操作發(fā)生
    INCF    DATA1,F      ;數據遞增
    INCF    ADDR,F       ;地址遞增
    MOVF    ADDR,W       ;
    XORLW   D’64’        ;將當前地址與64比較
    BTFSS   STATUS,Z     ;檢測=64否
    GOTO    WRITE        ;否！繼續(xù)寫后面單元
READ1
    DECF    ADDR,F       ;地址遞減
    BCF     STATUS,RP0   ;選體2為當前體 

BSF     STATUS,RP1   ;
    MOVF    ADDR,W       ;取地址
    MOVWF   EEADR        ;送地址寄存器
    BSF     STATUS,RP0   ;選體3為當前體
    BCF     EECON1,EEPGD  ;選定EEPROM為訪問對象
    BSF     EECON1,RD     ;啟動讀操作
    BCF     STATUS,RP0    ;體2為當前體
    MOVF    EEDATA,W      ;取數據
    BCF     STATUS,RP1    ;體0為當前體
    MOVWF   PORTC         ;送顯LED
    CALL    DELAY         ;調用廷時子程序
    MOVF    ADDR,F        ;檢測當前地址
    BTFSS   STATUS,Z      ;是否為0？是！跳一步
    GOTO    READ1         ;否！返回繼續(xù)讀出和顯示
READ2 
    INCF    ADDR,F        ;地址遞增
    BCF     STATUS,RP0    ;選體2為當前體
    BSF     STATUS,RP1    ;
    MOVF    ADDR,W        ;取地址
    MOVWF   EEADR         ;送地址寄存器
    BSF     STATUS,RP0     ;選體3為當前體
    BCF     EECON1,EEPGD   ;選定EEPROM為訪問對象
    BSF     EECON1,RD      ;啟動讀操作
    BCF     STATUS,RP0     ;體2為當前體
    MOVF    EEDATA,W       ;取數據 

BCF     STATUS,RP1     ;體0為當前體
    MOVWF   PORTC          ;送顯LED
    CALL    DELAY          ;調用廷時子程序
    MOVF    ADDR,W         ;檢測當前地址與64比較
    XORLW   D’64’          ;
    BTFSS   STATUS,Z       ;是否等于64
    GOTO    READ2          ;否！返回繼續(xù)讀出和顯示
    GOTO    READ1          ;返回大循環(huán)起點
;******************************************
DELAY
    MOVLW    0             ;
    MOVWF    72H           ;將外層循環(huán)參數值256送外層循環(huán)寄存器
DELAY1
    MOVLW     0            ;將內層循環(huán)參數值256送內層循環(huán)寄存器
    MOVWF    73H           ;
    DECFSZ   73H,1         ;遞減廷時程序
    GOTO     $-1           ;
    DECFSZ   72H,1         ;
    GOTO     DELAY1        ; 

RETURN
;********************************************
    END
;***************************************************** 

（文源網絡，侵刪）